Home / ubuntu / Questions / 889886
In Process
EdiD
Asked: 2017-03-06 10:08:53 +0800 CST

AWK print from pattern to pattern

  • 772

file: 

string1 string2 string3 string4 string5 string6  
string3 string1 string2 string4 string5 string6  
string6 string3 string2 string4 string1 string5

expectation: 

string2 string3 string4 string5  
string2 string4 string5  
string2 string4 string1 string5

Match pattern=string1
How to print match lines but only from string2 to string5 with awk ?

Unfortunately this is not processing in line : 

 awk '/string2/,/string5/' file

Let's assume there are few long lines with string2 and string5 in different places.

text-processing

4 Answers

  1. You can use awk's index and match functions e.g.

    awk 'match($0,/string5/) {
  START2 = index($0,"string2");
  print substr($0,START2,RSTART+RLENGTH-START2)
}' file

    Ex.

    $ mawk 'match($0,/string5/) {
  START2 = index($0,"string2");
  print substr($0,START2,RSTART+RLENGTH-START2)
}' file
string2 string3 string4 string5
string2 string4 string5
string2 string4 string1 string5

    Note this assumes that string2 will exist in every line in which string5 exists - if that's not the case, you will need to check the value of index($0,"string2") and act accordingly.

    • 3

  2. Effectively,what you want to do is iterate over each field, and "enable" printing with a variable if result is found. Thus, what you need is a flag variable and for loop:

    $ cat file.txt
string1 string2 string3 string4 string5 string6
string3 string1 string2 string4 string5 string6
string6 string3 string2 string4 string1 string5

$ awk '{flag=0;for(i=1;i<=NF;i++){ if($i=="string2") flag=1; if($i=="string6") flag=0;  if(flag)printf "%s%s",$i,FS;};print"";}' file.txt  
string2 string3 string4 string5 
string2 string4 string5 
string2 string4 string1 string5

    What happens here is that the whole code block will run for each line. On each line we are iterating from first field to last. Initially we set flag variable to 0, then proceed to examine each field. If field contains the desired "string2" , the flag will be set to 1, and if it is "string6" (which is the one when we want to stop) - flag will be set to 0; finally, if statement will check if flag is set and print the current field appended with field separator (represented by FS variable). After all has been printed we also insert new-line via print "" command.

    In case where you have lines without match, the above command will print blank lines. You can mitigate that via adding search pattern, which will limit code-block execution only when there is pattern found in string:

    $ cat file.txt
string1 string2 string3 string4 string5 string6
blah blah
string3 string1 string2 string4 string5 string6
string6 string3 string2 string4 string1 string5

$ awk '$0~"string2"{flag=0;for(i=1;i<=NF;i++){ if($i=="string2") flag=1;  if(flag)printf "%s%s",$i,FS;};print"";}' file.txt
string2 string3 string4 string5 string6 
string2 string4 string5 string6 
string2 string4 string1 string5

    Alternatively, we can use an extra variable with same result:

    $ awk '{j=0;f=0;for(i=1;i<=NF;i++){if($i=="string2"){j=1;f=1};if(f)printf "%s%s",$i,FS;};if(j)print"";}' file.txt        
string2 string3 string4 string5 string6 
string2 string4 string5 string6 
string2 string4 string1 string5
    • 3

  3. First, you only keep lines containing string2 and string5 in that particular order (pattern in line 1). All you have to do next is strip everything before string2 and everything after string5 (lines 2 and 3) and finally print what remains.

    awk '/string2 .* string5/ {
    sub(/^.*string2/, "string2", $0);
    sub(/string5.*$/, "string5", $0);
    print $0;
}'
    • 2

  4. Using grep:

    grep -Po '\bstring2.*string5\b' file.txt
    • 1