Home / server / Questions / 40156
Accepted
pQd
Asked: 2009-07-14 13:23:42 +0800 CST

puppet: force service restart after configuration file was modified

  • 772

how can i ensure that if new version of configuration file is downloaded via puppet from master repository to one of managed servers relevant service is restarted.

typical scenario - let's say there is new munin or apache config. puppet client discovers it, overwrites local files... and... - how to make sure service is restarted / reloaded ?

thanks a lot!

puppet configuration-management

5 Answers

  1. Best Answer

    An alternative to notify is subscribe:

    file { "/etc/sshd_config":
    source => "....",
}

service { sshd:
    ensure => running,
    subscribe => File["/etc/sshd_config"],
}

    The difference being that the relationship is described from the other end. For example, you might make apache subscribe to /etc/apache/httpd.conf, but you'd make a vhost file notify apache, as your apache class won't know about every vhost you have.

    A similar dual-ended situation applies to require and before. It's just a matter of which makes more sense in the particular situation.

    As Chad mentioned, if you find puppet constantly trying to start your service, then you need to add a pattern parameter, which is a regex to apply against the list of processes. By default puppet will do a stop and start to restart a service. If you add "hasrestart => true", then it will use the command specified in the "restart" parameter to restart the service.

    • 24

  2. it seems i've found something:

    file { "/etc/sshd_config":
    source => "....",
    notify => Service[sshd]
}

service { sshd:
    ensure => running
}

    we'll see how that will work. anyway your thoughts on the subject are welcome.

    • 22

  3. (I know this is a super old question, but just thought I'd put in my two cents with an (in my opinion) much easier way to do it)

    Feel free to use arrow notation as well:

    file { "/etc/sshd_config":
  source => "....",
} ~>
service { sshd:
  ensure => running
}

    or

    File['/etc/sshd_config'] ~> Service['sshd']
    • 2

  4. This works for Solaris 10 :)

    class sun_cron_root {
    file { "/var/spool/cron/crontabs/root" :
            source => "puppet:///files/cron/sun/sun_cron_root"
            }

    service {
            "cron":
            provider => "smf",
            ensure => running,
            enable => true,
            hasrestart => true,
            subscribe => File["/var/spool/cron/crontabs/root"]
            }

}
    • 1

  5. There are multiple equivalent notations:

    Notify:

    file { '/etc/sshd_config':
    notify => Service[sshd],
}

service { sshd:
    ensure => running
}

    Subscribe:

    file { '/etc/sshd_config':
   ...
}

service { sshd:
    ensure => running,
    subscribe => File['/etc/sshd_config'],
}

    Arrow notation:

    File['/etc/sshd_config'] ~> Service['sshd']

    Chaining declarations

    file { '/etc/sshd_config':
   ...
}
~> service { sshd:
    ensure => running,
}

    If you want to trigger reload instead of restart, adjust service declaration:

    service { sshd:
    ensure => running,
    restart => 'pkill -HUP sshd', # if service support such reload
}
    • 0