Home / server / Questions / 62578
Accepted
Chris Magnuson
Asked: 2009-09-05 12:46:51 +0800 CST

How to get a list of drive letters on a system through a windows shell (bat, cmd)?

  • 772

How do I get a list of drive letters and their associated labels on a windows system through a bat file?

windows batch-file windows-command-prompt

14 Answers

  1. Best Answer

    This will get most of it:

    Net Use

    If you have any drives mapped via subst you would also need to get those:

    Subst

    For completeness, you would do it like this in Powershell (if you are on windows 7 or have installed it):

    gwmi win32_LogicalDisk -filter DriveType=4

    You can also do it from the command prompt or a batch file using WMI like this:

    wmic logicaldisk get caption,providername,drivetype,volumename
    • 41

  2. To use diskpart, there is no need to create an intermediate file. Try:

    echo list volume | diskpart
    • 16 
  3. @echo off
cls
setlocal enabledelayedexpansion
set "_DRIVE.LETTERS.FREE=Z Y X W V U T S R Q P O N M L K J I H G F E D C B A "
for /f "skip=1 tokens=1,2 delims=: " %%a in ('wmic logicaldisk get deviceid^,volumename') do (
   set "_DRIVE.LETTERS.USED=!_DRIVE.LETTERS.USED!%%a,%%b@"
   set "_DRIVE.LETTERS.FREE=!_DRIVE.LETTERS.FREE:%%a =!"
)
set _DRIVE.LETTERS.USED=%_DRIVE.LETTERS.USED:~0,-2%
set _DRIVE.LETTERS.USED=%_DRIVE.LETTERS.USED:,@=, @%
set _DRIVE.LETTERS

    Fast, flexible and efficient. Although a little complex.

    • 11

  4. inspired by Scott

    for %i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do @%i: 2>nul && set/pz=%i <nul

    also shows CD drive letters and network mounted disk letters. No need to have admin rights.

    • 7 
  5. mountvol

    sample output

    \\?\Volume{11197e59-f977-11dd-afc6-111e6f6e6963}\
   *** NO MOUNTING POINT ***

\\?\Volume{11197e59-f977-11dd-afc6-111e6f6e6963}\
   D:\

\\?\Volume{11197e59-f977-11dd-afc6-111e6f6e6963}\
   C:\

\\?\Volume{11197e59-f977-11dd-afc6-111e6f6e6963}\
   E:\
    • 5

  6. If anyone is lucky enough to be using Vista (Vista Ultimate SP2 b6002, in my case) and the gwmi and wmic snippets given here don't work exactly, here is what I did to make it work.

    For gwmi, if you receive no output, try changing the DriveType to 3. If still having problems, remove the -filter option altogether and analyze output.

    gwmi win32_LogicalDisk -filter DriveType=3

    For wmic, if you receive "Invalid GET Expression", then try putting the get expression in quotes:

    wmic logicaldisk get "caption,providername,drivetype,volumename"
    • 4 
  7. @echo off
echo list volume > scriptdiskpart
diskpart/s scriptdiskpart
del scriptdiskpart
pause
    • 2

  8. This site has a much simpler set of calls:

    http://en.code-bude.net/2013/02/23/show-all-drives-in-command-prompt/

    Show local drives:

    wmic logicaldisk get deviceid, volumename, description

    If you want to show only drives of a particular type, the wmic command can be further expanded to include a where clause.

    wmic logicaldisk where drivetype=2 get deviceid, volumename, description

    Types

    0 => Unknown

    1 => No Root Directory

    2 => Removable Disk

    3 => Local Disk

    4 => Network Drive

    5 => Compact Disc

    6 => RAM Disk

    • 2 
  9. for %a in (c: d: e: f: g: h: i: j: k: l: m: n: o: p: q: r: s: t: u: v: w: x: y: z:) do @vol %a 2>&1 | find "drive"

    I found the diskpart approach reports DVD drives with no disc inserted, and doesn't report SD cards with valid drive volumes

    • 1 
  10. for %%p in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do if exist %%p:\nul your_command_and_parameters_here
    • 1