Home / server / Questions / 1168523
Accepted
Peter Kahn
Asked: 2024-12-05 03:28:56 +0800 CST

Is it possible to create azure subscription quota alerts using terraform azurerm provider?

  • 772

I see that azurerm provider has azurerm_monitor_metric_alert but does not appear to support azure quota alerts. Various AI think I can use azurerm_monitor_metric_alert with a scope like `/subscriptions/${data.azurerm_subscription.current.subscription_id}/providers/Microsoft.Compute/locations/${location}/providers/Microsoft.Quota/quotas/standardDPLDSv5Family"

but this doesn't seem to be the case. It seems to be impossible to manage subscription quota alerts via terraform. Is this right?

azure

1 Answers

  1. Best Answer

    This is what worked for me.

    Try using resource azurerm_monitor_scheduled_query_rules_alert_v2:

    resource "azurerm_monitor_scheduled_query_rules_alert_v2" "quota_alerts" {
  name                              = "quota-alerts"
  resource_group_name               = azurerm_resource_group.rg.name
  location                          = azurerm_resource_group.rg.location
  evaluation_frequency              = "PT5M"
  window_duration                   = "PT15M"
  scopes                            = [var.subscription-id]
  severity                          = 2
  description                       = "Quota Usage Alert Rule >=70%"
  display_name                      = "Quota Usage Alert Rule"
  enabled                           = true
  auto_mitigation_enabled           = true
  criteria {
    query                   = <<-QUERY
    arg("").QuotaResources
        | where subscriptionId =~ '${var.subscription-id}'
        | where type =~ 'microsoft.compute/locations/usages'
        | where isnotempty(properties)
        | mv-expand propertyJson = properties.value limit 400
        | extend
        usage = propertyJson.currentValue,
        quota = propertyJson.['limit'],
        quotaName = tostring(propertyJson.['name'].value)
        | extend usagePercent = toint(usage)*100 / toint(quota)| project-away properties| where quotaName in~ ('Standard NCASv3_T4 Family')
      QUERY
    time_aggregation_method = "Maximum"
    threshold               = 70
    operator                = "GreaterThanOrEqual"

    metric_measure_column = "usagePercent"
    dimension {
        name     = "location"
        operator = "Include"
        values   = ["*"]
    }
    dimension {
        name     = "quotaName"
        operator = "Include"
        values   = ["Standard NCASv3_T4 Family"]
    }
    dimension {
        name     = "type"
        operator = "Include"
        values   = ["microsoft.compute/locations/usages"]
    }
    failing_periods {
      minimum_failing_periods_to_trigger_alert = 1
      number_of_evaluation_periods             = 1
    }
  }

  action {
    action_groups = [azurerm_monitor_action_group.admin.id]
  }

  identity {
    type = "UserAssigned"
    identity_ids = [
      azurerm_user_assigned_identity.subscription-reader.id,
    ]
  }
}
    • 0