Home / server / Questions / 581419
Accepted
Tuinslak
Asked: 2014-03-12 14:12:06 +0800 CST

Puppet: include other files depending on hostname

  • 772

I'm trying to get something like this to work in my Puppet manifest:

    if $hostname == 'host1' || $hostname == 'host2' {
        # Modified config.txt for portrait mode. 
        file { '/boot/config.txt' :
            ensure      => present,
            mode        => '0755',
            source      => 'puppet://puppet/files/boot/config.txt.portrait',
        }
    } else {
        # Normal config.txt for landscape mode.
        file { '/boot/config.txt' :
            ensure      => present,
            mode        => '0755',
            source      => 'puppet://puppet/files/boot/config.txt.landscape',
        }
    }

However, this fails. What is the best way to, depending on the hostname, to include different files?

puppet

5 Answers

  1. Best Answer

    An alternative syntax would be to use a selector in your source parameter.

    file { '/boot/config.txt' :
    ensure      => present,
    mode        => '0755',
    source      => $::hostname?{
                      'host1' => 'puppet://puppet/files/boot/config.txt.portrait',
                      'host2' => 'puppet://puppet/files/boot/config.txt.portrait',
                      default => 'puppet://puppet/files/boot/config.txt.landscape',
                    },
}
    • 6

  2. Building on what devicenull said, you can then shorten it further by using selective file source(s):

    # Normal config.txt for landscape mode.
file { '/boot/config.txt' :
    ensure      => present,
    mode        => '0755',
    source      => [ 
         "puppet://puppet/files/boot/config.txt.$hostname", # down the individual hostname if required
         "puppet://puppet/files/boot/config.txt.$layouttype", # a layout dimension fact (portrait/landscape)
         "puppet://puppet/files/boot/config.txt" # default
    ],
}

    I've got many examples like these in my manifests where relatively static files are needed for a host type (not often down to hostname level), but definitely $domain, and a custom fact $site_location (external, datacentre, office, etc) is used extensively.

    • 3

  3. For what you're asking I'd use Case Statements. 

        case $hostname {
      'host1', 'host2': { # Modified config.txt for portrait mode. 
        file { '/boot/config.txt' :
            ensure      => present,
            mode        => '0755',
            source      => 'puppet://puppet/files/boot/config.txt.portrait',
        }  
      } 
      default:            { 
        file { '/boot/config.txt' :
            ensure      => present,
            mode        => '0755',
            source      => 'puppet://puppet/files/boot/config.txt.landscape',
        }
      } # apply the generic class
    }
    • 2

  4. Tuinslak!

    We solved our problem like this:

           if $hostname =~ /^sv-dns./ {
               file { '/etc/chrony.conf':
                  ensure => file,
                  owner  => 'root',
                  group  => 'root',
                  mode   => '0644',
                  source => [ 'puppet:///modules/basico/conf/ntp_server/chrony.conf_server' ]
               }
    } else {
               file { '/etc/chrony.conf':
                  ensure => file,
                  owner  => 'root',
                  group  => 'root',
                  mode   => '0644',
                  source => [ 'puppet:///modules/basico/conf/ntp_server/chrony.conf_client' ]
               }
    }

    We have two different types of chronyd configuration files: one for all the regular machines and one for all the DNS servers who act like a NTP server inside our network. We have a name convention here, that every DNS server has the hostname started with "sv-dns". So with the snippet above we can assure that every hostname, wich its name starts with "sv-dns" will receive the chrony.conf_server file and all other servers will receive the chrony.conf_client file.

    If your hostname is fixed for example dnsmachine.some.domain you can use the example provided by @kwiksand:

    file { '/boot/config.txt' :
ensure      => present,
mode        => '0755',
source      => $::hostname?{
                  'host1' => 'puppet://puppet/files/boot/config.txt.portrait',
                  'host2' => 'puppet://puppet/files/boot/config.txt.portrait',
                  default => 'puppet://puppet/files/boot/config.txt.landscape',
                },

    Best regards,

    Adail

    • 1

  5. I had to use "or" instead of ||:

        if $hostname == 'host1' or $hostname == 'host2' {
    • 0